package com.pcornejo
{
	import com.google.maps.MapOptions;
	import com.google.maps.services.Directions;
	import com.google.maps.services.DirectionsEvent;
	import com.google.maps.services.DirectionsOptions;
	import fl.controls.Button;
	import fl.controls.TextInput;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.GeolocationEvent;
	import flash.events.MouseEvent;
	import flash.events.StatusEvent;
	import flash.events.TouchEvent;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.net.dns.SRVRecord;
	import flash.sensors.Geolocation;
	import flash.text.TextField;
	import flash.ui.Multitouch;
	import flash.ui.MultitouchInputMode;
 
	import com.google.maps.LatLng;
	import com.google.maps.Map;
	import com.google.maps.MapEvent;
	import com.google.maps.MapType;
	import com.google.maps.overlays.Marker;
 
	/**
	 * Main
	 * @author Patricio Cornejo
	 * http://www.pcornejo.com
	 */
 
	public class Main extends MovieClip
	{
		private const key:String = ""; // Obténla en http://code.google.com/intl/es-ES/apis/maps/signup.html
		private const url:String = "";
		private const loc:String = "en"; //es - en - fr
		private const tpo:Number = 1000;
 
		private var map:Map;
		private var geo:Geolocation;
		private var ubi_btn:Button;
		private var dir_btn:Button;
		private var dir_ti:TextInput;
		private var bsc_btn:Button;
		private var sz:MovieClip;
		private var txt:TextField;
 
		private var ubi:Marker;
		private var dir:Directions;
 
		private var lat:Number = 0;
		private var long:Number = 0;
		private var ubi_activado:Boolean = false;
		private var dir_activado:Boolean = false;
 
		public function Main():void
		{
			addEventListener(Event.ADDED_TO_STAGE, configUI);
		}
 
		private function configUI(e:Event):void
		{
			txt = new TextField();
			stage.addChild(txt);
 
			configGps();
			removeEventListener(Event.ADDED_TO_STAGE, configUI);
		}
 
		private function configTouch():void
		{
			if (Multitouch.supportsTouchEvents) {
				Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT;
			}
		}
 
		private function configDir():void
		{
			var dir_opts:DirectionsOptions = new DirectionsOptions( { locale: loc } );
 
			dir = new Directions();
			dir.setOptions(dir_opts);
			dir.addEventListener(DirectionsEvent.DIRECTIONS_SUCCESS, dirOk);
			dir.addEventListener(DirectionsEvent.DIRECTIONS_FAILURE, dirFail);
 
		}
 
		private function configUbi():void
		{
			ubi = new Marker(new LatLng(0, 0));
			ubi.visible = false;
			map.addOverlay(ubi);
		}
 
		private function configGps():void
		{
			if (Geolocation.isSupported) {
				configMap(); configTouch();
 
				geo = new Geolocation();
				geo.setRequestedUpdateInterval(tpo);
				geo.addEventListener(StatusEvent.STATUS, statusGeo);
			} else {
				//
			}
		}
 
		private function configMap():void
		{
			map = new Map();
			map.key = key; map.url = url;
			map.setSize(new Point(stage.stageWidth, stage.stageHeight));
			map.addEventListener(MapEvent.MAP_READY, onMapReady);
			this.addChild(map);
		}
 
		private function statusGeo(e:StatusEvent):void
		{
			//
		}
 
		private function updateGeo(e:GeolocationEvent):void
		{
			lat = e.latitude; long = e.longitude;
 
			if (ubi_activado) {
				ubi.visible = true;
				map.setCenter(new LatLng(lat, long), 14);
				ubi.setLatLng(new LatLng(lat, long));
			}
		}
 
		private function dirFail(e:DirectionsEvent):void
		{
			dir_ti.text = "fail direccion";
		}
 
		private function dirOk(event:DirectionsEvent):void
		{
			var dir:Directions = event.directions;
			dir_ti.text = "ok direccion";
			map.clearOverlays();
			map.addOverlay(dir.createPolyline());
			map.setCenter(dir.bounds.getCenter(), map.getBoundsZoomLevel(dir.bounds));
			map.addOverlay(new Marker(dir.getGeocode(0).point));
		}
 
		private function onMapReady(e:Event):void
		{
			crearUbi(); configUbi(); configDir(); crearDir();
			geo.addEventListener(GeolocationEvent.UPDATE, updateGeo);
		}
 
		private function crearDir():void
		{
			dir_btn = new Button();
			dir_btn.width = dir_btn.height = 100;
			dir_btn.label = "Direction";
			dir_btn.addEventListener(TouchEvent.TOUCH_TAP, verBarra);
			dir_btn.x = stage.stageWidth - dir_btn.width - ubi_btn.width - 30;
			dir_btn.y = stage.stageHeight - dir_btn.height - 20;
			addChild(dir_btn);
		}
 
		private function verBarra(e:TouchEvent):void
		{
			if (dir_activado) {
				dir_activado = false;
				dir_btn.label = "Direction";
				removeChild(dir_ti); removeChild(bsc_btn);
				return;
			} else {
				dir_activado = true;
				dir_btn.label = "Disable";
			}
 
			dir_ti = new TextInput();
			dir_ti.width = 300; dir_ti.height = 60;
			dir_ti.x = 20; dir_ti.y = 100; addChild(dir_ti);
			dir_ti.text = "77 Massachusetts Avenue, Cambridge, MA to 4 Yawkey Way, Boston, MA 02215 (Fenway Park)";
 
			bsc_btn = new Button();
			bsc_btn.x = dir_ti.x + dir_ti.width + 10;
			bsc_btn.y = dir_ti.y; bsc_btn.width = 60; bsc_btn.height = 60;
			bsc_btn.label = "Search";
			bsc_btn.addEventListener(TouchEvent.TOUCH_TAP, buscarDir);
			addChild(bsc_btn);
		}
 
		private function buscarDir(e:TouchEvent):void
		{
			dir.load(dir_ti.text);
		}
 
		private function crearUbi():void
		{
			ubi_btn = new Button();
			ubi_btn.width = ubi_btn.height = 100;
			ubi_btn.label = "Ubication";
			ubi_btn.addEventListener(TouchEvent.TOUCH_TAP, verUbicacion);
			ubi_btn.x = stage.stageWidth - ubi_btn.width - 20;
			ubi_btn.y = stage.stageHeight - ubi_btn.height - 20;
			addChild(ubi_btn);
		}
 
		private function verUbicacion(e:TouchEvent):void
		{
			if (ubi_activado) {
				ubi_activado = ubi.visible = false;
				ubi_btn.label = "Ubication";
			} else {
				ubi_activado = true;
				ubi_btn.label = "Disable";
 
				if (lat != 0) {
					ubi.visible = true;
					map.setCenter(new LatLng(lat, long), 14);
					ubi.setLatLng(new LatLng(lat, long));
				}
			}
		}
	}
 
}

package com.pcornejo 
{
	import com.transmote.flar.FLARManager;
	import com.transmote.flar.marker.FLARMarker;
	import com.transmote.flar.marker.FLARMarkerEvent;
	import com.transmote.flar.utils.geom.FLARPVGeomUtils;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import org.libspark.flartoolkit.support.pv3d.FLARCamera3D;
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.lights.PointLight3D;
	import org.papervision3d.materials.BitmapColorMaterial;
	import org.papervision3d.materials.BitmapFileMaterial;
	import org.papervision3d.materials.ColorMaterial;
	import org.papervision3d.materials.utils.MaterialsList;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.parsers.DAE;
	import org.papervision3d.render.LazyRenderEngine;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.view.Viewport3D;
 
	/**
	 * Usando FlarManager Realidad Aumentada
	 * @author Patricio Cornejo
	 * http://www.pcornejo.com
	 */
 
	[SWF(width = "640", height = "480", backgroundColor="#000000", frameRate="40")]
	public class FLARM extends Sprite
	{
		private var fm:FLARManager;
		private var activeMarker:FLARMarker;
 
		private var scene3D:Scene3D;
		private var camera3D:Camera3D;
		private var viewport3D:Viewport3D;
		private var render:LazyRenderEngine;
		private var pointLight3D:PointLight3D;
		private var dp3D:DisplayObject3D;
		private var model:DAE;
 
		public function FLARM():void
		{
			addEventListener(Event.ADDED_TO_STAGE, configUI);
		}
 
		private function configUI(e:Event):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, configUI);
			configFLAR();
		}
 
		private function configFLAR():void
		{
			fm = new FLARManager("./xml/config.xml");
			fm.thresholdSourceDisplay = false; //Colocar true para ver el depurador de Threshold
			addChild(Sprite(fm.flarSource));
 
			fm.addEventListener(FLARMarkerEvent.MARKER_ADDED, onMarkerAdded);
			fm.addEventListener(FLARMarkerEvent.MARKER_REMOVED, onMarkerRemoved);
			fm.addEventListener(FLARMarkerEvent.MARKER_UPDATED, onMarkerUpdated);
			fm.addEventListener(Event.INIT, configPv3d);
		}
 
		private function configPv3d (evt:Event) :void
		{
			scene3D = new Scene3D();			
			camera3D = new FLARCamera3D(fm.cameraParams);			
			viewport3D = new Viewport3D(stage.stageWidth, stage.stageHeight);
			addChild(viewport3D);
 
			render = new LazyRenderEngine(scene3D, camera3D, viewport3D);
			pointLight3D = new PointLight3D();
			pointLight3D.x = 1000;
			pointLight3D.y = 1000;
 
			model = new DAE(true, "model", true);
			model.load("daes/duck.dae");
			model.rotationX = 90; model.rotationZ = -90;
 
			dp3D = new DisplayObject3D();
			dp3D.addChild(model);
			dp3D.visible = false;
			scene3D.addChild(dp3D);
 
			addEventListener(Event.ENTER_FRAME, onEnterFrame);
		}
 
		private function onMarkerAdded (evt:FLARMarkerEvent) :void 
		{
			dp3D.visible = true;
			activeMarker = evt.marker;
		}
		private function onMarkerUpdated (evt:FLARMarkerEvent) :void 
		{
			dp3D.visible = true;
			activeMarker = evt.marker;
		}
 
		private function onMarkerRemoved (evt:FLARMarkerEvent) :void
		{
			dp3D.visible = false;
			activeMarker = null;
		}
 
		private function onEnterFrame (evt:Event) :void
		{
			if (activeMarker) {
				dp3D.transform = FLARPVGeomUtils.convertFLARMatrixToPVMatrix(activeMarker.transformMatrix);
			}
 
			render.render();
		}
 
	}
 
}

package com.pcornejo
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.filters.DisplacementMapFilter;
	import flash.filters.DisplacementMapFilterMode;
	import flash.geom.Point;
 
	/**
	 * Reflejo Agua
	 * @author Patricio Cornejo
	 * @link www.pcornejo.com
	 */
 
	[SWF(width = "750", height = "501", backgroundColor = "0x000000")]
	public class Main extends Sprite
	{
		[Embed(source = "../../../lib/lago.jpg")]
		private var Lago:Class;
 
		[Embed(source = "../../../lib/agua.png")]
		private var Agua:Class;
 
		private var lake:Bitmap;
		private var water:Bitmap;
 
		private var pt1:Point;
		private var pt2:Point;
		private var pt3:Point;
 
		private var ola1:BitmapData;
		private var ola2:BitmapData;
		private var ola3:BitmapData;
 
		private var dm1:DisplacementMapFilter;
		private var dm2:DisplacementMapFilter;
		private var dm3:DisplacementMapFilter;
 
		public function Main():void
		{
			addEventListener(Event.ADDED_TO_STAGE, configUI);
		}
 
		private function configUI(e:Event):void
		{
			cargarFotos(); configReflex();
			addEventListener(Event.ENTER_FRAME, efectoReflex);
		}
 
		private function cargarFotos():void
		{
			lake = new Lago();
			water = new Agua();
 
			water.y = stage.stageHeight - water.height;
			addChild(lake);	addChild(water);
		}
 
		private function configReflex():void
		{
			pt1 = new Point();
			//pt2 = new Point();
			//pt3 = new Point();
 
			ola1 = new BitmapData(stage.stageWidth, water.height);
			//ola2 = new BitmapData(stage.stageWidth, water.height);
			//ola3 = new BitmapData(stage.stageWidth, water.height);
 
			dm1 = new DisplacementMapFilter(ola1, new Point(0, 10), 0, 4, 0, 10, DisplacementMapFilterMode.CLAMP);
			//dm2 = new DisplacementMapFilter(ola2, new Point(0, 40), 0, 4, 0,50, DisplacementMapFilterMode.CLAMP);
			//dm3 = new DisplacementMapFilter(ola3, new Point(0, 20), 0, 4, 0, 50, DisplacementMapFilterMode.CLAMP);
		}
 
		private function efectoReflex(e:Event):void
		{
			pt1.y -= .2;
			//pt2.y -= .4; pt3.y -= .8;
			ola1.perlinNoise(40, 5, 1, 0, true, true, 4, true, [pt1]);
			//ola2.perlinNoise(40, 4, 2, 0, true, true, 4, true, [pt2]);
			//ola3.perlinNoise(80, 8, 1, 0, true, false, 4, true, [pt3]);
			water.filters = [dm1];
		}
 
	}
 
}

package com.pcornejo
{
	import flash.display.Loader;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import gs.TweenMax;
 
	/**
	 * Gallery Flash Player 10 3D Tools
	 * @author Patricio Cornejo
	 * @link http://www.pcornejo.com
	 */
 
	[SWF(framerate = 40, width = 1000, height = 600, backgroundColor=0x000000)]
	public class Main extends Sprite
	{
		private const xml_url:String = "xml/fotos.xml";
		private const col:Number = 6; //Numero de columnas
 
		private var pre:TextField;
		private var caja:Sprite; //contenedor de los thumbnails
		private var num:Number; //numero total de fotos
		private var xml:XML;
		private var fotoActual:MovieClip; //foto actual en acercamiento
 
		private var n:Number = 0;
		private var ldrs:Array = [];
		private var dirX:Number = 0;
		private var dirY:Number = 0;
 
		public function Main():void
		{
			addEventListener(Event.ADDED_TO_STAGE, configUI);
		}
 
		//Configuramos el Escenario
		private function configUI(e:Event):void
		{
			pre = new TextField();
			caja = new Sprite();
 
			pre.textColor = 0xffffff;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			cargarXML(); addChild(pre); addChild(caja);
			stage.addEventListener(Event.RESIZE, ordenarObjetos);
			addEventListener(Event.ENTER_FRAME, moverCaja);
		}
 
		//Cargamos el archivo XML;
		private function cargarXML():void
		{
			var uldr:URLLoader = new URLLoader(new URLRequest(xml_url));
			uldr.addEventListener(Event.COMPLETE, alCargar);
		}
 
		//Parseamos el archivo XML
		private function alCargar(e:Event):void
		{
			xml = new XML(e.target.data);
			num = xml.foto.length();
			cargarFotos(null);
			ordenarObjetos(null);
		}
 
		//Cargamos las Fotos
		private function cargarFotos(e:Event):void
		{
			if (n < num) {
				if (n < 10)
					pre.text = "0" + (n + 1) +"/" + num;
				else
					pre.text =  (n + 1) +"/" + num;
 
				var ldr:Loader = new Loader();
				ldr.load(new URLRequest("images/prev/" + xml.foto[n].text()));
				ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, cargarFotos);
				ldrs.push(ldr); n++;
			} else {
				cargarThumbs(); //Al Completar la carga de todas las fotos, las colocamos al Escenario
			}
		}
 
		/* Creamos un contenedor para cada foto y lo colocamos en el escenario
		 * dándole una animacion de Entrada.
		 */
		private function cargarThumbs():void
		{
			var i:Number = 0;
 
			for each(var ldr:Loader in ldrs)
			{
				var mc:MovieClip = new MovieClip();
				mc.x = stage.stageWidth * .5 - caja.x - mc.width;
				mc.y = stage.stageHeight;
				mc.rotationX = mc.rotationY = 360;
				TweenMax.to(mc, .5, { x: 165 * dirX - (col / 2) * 165, y:125 * dirY - (((num / col) / 2) * 125), rotationX: 0, rotationY: 0, delay: .1 * i } );
				dirX++;	mc.addEventListener(MouseEvent.CLICK, clickThumb);
 
				if (dirX == col) {
					dirX = 0; dirY++;
				}
 
				i++; mc.addChild(ldr);
				caja.addChild(mc);
			}
		}
 
		/* Al hacer click sobre el Thumb manejamos el z, x e y del contenedor
		 * para lograr un efecto de acercamiento.
		 */
		private function clickThumb(e:MouseEvent):void
		{
			var obj:Object = new Object();
			obj.x = - e.currentTarget.x + 165 * 2;
			obj.y = - e.currentTarget.y + 125 * 2;
			obj.z = -400;
			//obj.bezierThrough = [ { x:0, y:0, z:0 } ];
 
			if (fotoActual != null && fotoActual != e.currentTarget)
				fotoActual.addEventListener(MouseEvent.CLICK, clickThumb);
 
			fotoActual = MovieClip(e.currentTarget);
			fotoActual.removeEventListener(MouseEvent.CLICK, clickThumb);
			fotoActual.addEventListener(MouseEvent.CLICK, volverThumb);
			TweenMax.to(caja, 1, obj);
		}
 
		/* Al hacer click sobre el mismo objeto visualizado
		 * volvemos atrás
		 */
		private function volverThumb(e:MouseEvent):void
		{
			e.currentTarget.removeEventListener(MouseEvent.CLICK, volverThumb);
			e.currentTarget.addEventListener(MouseEvent.CLICK, clickThumb);
			TweenMax.to(caja, 1, { x: stage.stageWidth * .5, y: stage.stageHeight * .5, z: 0, onComplete: function():void { fotoActual == null; } } );
		}
 
		//Efecto de moviemiento al mouse
		private function moverCaja(e:Event):void
		{
			caja.rotationY = (stage.stageWidth - stage.mouseX) / 500;
			caja.rotationX = (stage.stageHeight - stage.mouseY) / 500;
		}
 
		//ordenamos el contenedor delos thumbnails al centro del escenario
		private function ordenarObjetos(e:Event):void
		{
			caja.x = stage.stageWidth * .5;
			caja.y = stage.stageHeight* .5;
		}
	}
}